package JWebmail v1.2.1;

use Mojo::Base Mojolicious;

use Module::Load 'load';

use JWebmail::Controller::Webmail;
use JWebmail::Model::ReadMails::Role;
use JWebmail::Model::ReadMails::QMailAuthuser;
use JWebmail::Model::WriteMails;


sub validateConf {
    my $self = shift;

    my $conf = $self->config;

    exists $conf->{session}{secure} or die;
    grep(sub { $_ eq $conf->{session}{secure} }, qw(none cram s3d)) > 0 or die;

    exists $conf->{defaults}{scriptadmin} or die;
    $conf->{defaults}{scriptadmin} =~ /@/ or die;

    return 1;
}


sub startup {
    my $self = shift;

    $self->moniker('jwebmail');

    # load plugins
    push @{$self->plugins->namespaces}, 'JWebmail::Plugin';

    $self->plugin('TOMLConfig');
    $self->validateConf;

    if (my $logpath = $self->config('logpath')) {
        $self->log->path($logpath . '/' . $self->mode . '.log');
    }

    if (fc $self->config->{session}{secure} eq fc 's3d') {
        $self->plugin('ServerSideSessionData');
    }
    $self->plugin('Helper');
    my $i18n_route = $self->plugin('I18N2', $self->config('i18n'));

    $self->secrets( [$self->config('secret')] ) if $self->config('secret');
    delete $self->config->{secret};

    # initialize models
    my $read_mails = do {
        if ($self->mode eq 'development') {
            my $cls = $self->config->{model}{read}{devel}{driver};
            eval { load $cls; 1 } || die "Issue for module $cls with: $@";
            $cls->new(($self->config->{model}{read}{devel} // {})->%*)
        }
        else {
            JWebmail::Model::ReadMails::QMailAuthuser->new(
                ($self->config->{model}{read}{prod} // {})->%*
            )
        }
    };
    die "given class @{[ ref $read_mails ]} does not ReadMails"
        unless $read_mails->DOES('JWebmail::Model::ReadMails::Role');
    $self->helper(users => sub { $read_mails });
    $self->helper(send_mail => sub { my ($c, $mail) = @_; JWebmail::Model::WriteMails::sendmail($mail) });
    $JWebmail::Model::WriteMails::Block_Writes = 1
        if $self->mode eq 'development' && $self->config->{model}{write}{devel}{block_writes};

    $self->defaults(version => __PACKAGE__->VERSION);

    $self->sessions->cookie_name('jwebmail_session');
    $self->sessions->samesite('Strict');
    $self->sessions->secure(1);
    $self->sessions->default_expiration(30 * 60);

    $self->route($i18n_route);
}


sub route {
    my $self = shift;

    my $r = shift || $self->routes;

    $r->get('/' => 'login')->to('Webmail#noaction');
    $r->post('/' => 'login')->to('Webmail#login');
    $r->get('/about')->to('Webmail#about');
    $r->get('/logout')->to('Webmail#logout');

    my $a = $r->under('/')->to('Webmail#auth');
    $a->get('/home/*folder')->to('Webmail#displayheaders', folder => '')->name('displayheaders');
    $a->get('/read/#id' => 'read')->to('Webmail#readmail');
    $a->get('/write')->to('Webmail#writemail');
    $a->post('/write' => 'send')->to('Webmail#sendmail');
    $a->post('/move')->to('Webmail#move');
}


1

__END__

=encoding utf-8

=head1 NAME

JWebmail - Provides a web based e-mail client meant to be used with s/qmail.

=head1 SYNOPSIS

    hypnotoad script/jwebmail

And use a server in reverse proxy configuration. 

=head1 DESCRIPTION

=head1 CONFIGURATION

Use the I<jwebmail.conf> file or for a specific I<$mode> the I<jwebmail.$mode.conf>.

=head1 AUTHORS

Copyright (C) 2020-2022 Jannis M. Hoffmann L<jannis@fehcom.de>

=head1 BASED ON IDEAS

Copyright (C) 2001 Olivier Müller L<om@omnis.ch> (GPLv2+ project: oMail Webmail)

Copyright (C) 2000 Ernie Miller (GPL project: Neomail)

See the CREDITS file for project contributors.

=head1 LICENSE

This module is licensed under the terms of the GPLv3.
Please take a look at the provided LICENSE file shipped with this module.

=cut