project(
  'sqmail',
  'c',
  'cpp',
  meson_version : '>=1.3',
  version : '4.2.29a',
  default_options : ['c_std=gnu99', 'cpp_std=c++11'],
)

qlibs_dep = dependency('qlibs', fallback : ['fehQlibs', 'qlibs_dep'])
dnsresolv_dep = dependency('dnsresolv', fallback : ['fehQlibs', 'qlibs_dnsresolv_dep'])

if get_option('build-clients') or get_option('build-pam')
  ucspissl_dep = dependency(
    'ucspissl',
    fallback : ['ucspi-ssl', 'ucspissl_dep'],
    default_options : ['lib-only=true'],
  )
else
  ucspissl_dep = disabler()
endif

crypt_dep = get_option('build-pam') ? dependency('libcrypt') : disabler()

if get_option('build-clients')
  idn2_dep = dependency('libidn2', required : get_option('idn2'))
else
  idn2_dep = disabler()
endif

if get_option('build-clients') or get_option('build-dkim') or get_option('build-pam')
  ssl_dep = dependency('libssl', version : '>=1.1')
  crypto_dep = dependency('libcrypto')
else
  ssl_dep = disabler()
  crypto_dep = disabler()
endif

subdir('src')
subdir('man')
subdir('tests')